module uiuart_tx#
(
 parameter integer BAUD_DIV     = 216 //设置采样系数(时钟/采样率-1),便于外部修改
)
(
        input       I_clk,
    input       I_uart_rstn,
        input       I_uart_wreq,//发送数据请求
    input [7:0] I_uart_wdata,//发送数据
    output      O_uart_wbusy,//发送状态忙,即是否正在发送数据
        output      O_uart_tx//发送总线
);

localparam UART_LEN = 4'd10;//设置uart发送的bit数量为10,代表1bit起始位,8bits数据,1bit停止位
wire        bps_en ;//发送使能
reg         uart_wreq_r   = 1'b0;//寄存一次发送数据请求
reg         bps_start_en    = 1'b0;//波特率计数器启动使能，也是发送启动使能
reg [13:0]  baud_div        = 14'd0;//波特率计数器
reg [9 :0]  uart_wdata_r  = 10'h3ff;//寄存10bit数据(1+8+1)
reg [3 :0]  tx_cnt          = 4'd0;//计数已经发送出多少位数据

assign O_uart_tx = uart_wdata_r[0];//从低位开始输出,且总线上的数据始终为uart_wdata_r[0]

assign O_uart_wbusy = bps_start_en;//发送启动使能有效时,处于发送忙状态

// uart tx Baud rate divider
assign bps_en = (baud_div == BAUD_DIV);//产生一次发送使能信号,条件是baud_div == BAUD_DIV,波特率计数达成

//波特率计数器
always@(posedge I_clk )begin
    if((I_uart_rstn== 1'b0) || (I_uart_wreq==1'b1&uart_wreq_r==1'b0))begin
        baud_div <= 14'd0;
    end
    else begin
        if(bps_start_en && baud_div < BAUD_DIV)//发送使能为1时,进行波特率计数
            baud_div <= baud_div + 1'b1;
        else 
            baud_div <= 14'd0;
    end
end

always@(posedge I_clk)begin
    uart_wreq_r <= I_uart_wreq;//寄存一次发送请求
end

//UART transmit enable ,Support gapless continuous enable
always@(posedge I_clk)begin
    if(I_uart_rstn == 1'b0)
        bps_start_en    <= 1'b0;
    else if(I_uart_wreq==1'b1&uart_wreq_r==1'b0) 
        bps_start_en    <= 1'b1;
    else if(tx_cnt == UART_LEN)
        bps_start_en    <= 1'b0;
    else 
        bps_start_en    <= bps_start_en;
end

//UART transmiter BIT counter
always@(posedge I_clk)begin
    if(((I_uart_rstn== 1'b0) || (I_uart_wreq==1'b1&uart_wreq_r==1'b0))||(tx_cnt == 10))
        tx_cnt <=4'd0;//复位、启动发送、发送完成,重置tx_cnt
    else if(bps_en && (tx_cnt < UART_LEN))
        tx_cnt <= tx_cnt + 1'b1;//tx_cnt计数器,每发送一个bit加1
end

//uart send controller shift control
always@(posedge I_clk)begin
    if((I_uart_wreq==1'b1&uart_wreq_r==1'b0)) 
        //寄存需要发送的数据,包括1bit起始位,8bits数据,1bit停止位
        uart_wdata_r  <= {1'b1,I_uart_wdata[7:0],1'b0};
    else if(bps_en && (tx_cnt < (UART_LEN - 1'b1)))//shift 9 bits
        //并串转换，将并行数据依次传输
        uart_wdata_r <= {uart_wdata_r[0],uart_wdata_r[9:1]};
    else 
        uart_wdata_r <= uart_wdata_r;

end   

endmodule
复制代码

module uart_top
(
input I_sysclk,  //系统时钟输入
output O_uart_tx  //UART串口发送总线
);


wire     uart_rstn; //内部同步复位
wire     uart_wbusy;//UART发送驱动器正忙
reg      t1s_dly_en;//1S延迟
reg[1:0] S_UART_TX;//UART 发送状态机
reg[3:0] tx_index;//发送index计数器
reg      uart_wreq;//UART发送请求
reg[7:0] uart_wdata;//UART发送数据寄存器
reg[7:0] uart_tx_buf[0:11];//发送缓存

reg [15:0]rst_cnt = 16'd0;//复位计数器
reg [24:0]delay_cnt = 25'd0;//延迟计数器

assign uart_rstn = rst_cnt[15];

//Power-on Reset Delay
always @(posedge I_sysclk)begin
    rst_cnt <= (rst_cnt[15] == 1'b0) ? (rst_cnt + 1'b1) : rst_cnt ;
end

//帧延迟计数器
always @(posedge I_sysclk)begin
        if(t1s_dly_en == 1'b0)
            delay_cnt <= 25'd0;
    else 
            delay_cnt <= delay_cnt + 1'b1;
end

//数据发送状态机
//初始化uart_tx_buf,hello fpga等字符共计12 BYTES,以及其他寄存器
always @(posedge I_sysclk)begin
    if(uart_rstn==1'b0)begin
        uart_tx_buf[0]  <=8'h48;//h
        uart_tx_buf[1]  <=8'h45;//e
        uart_tx_buf[2]  <=8'h4c;//l
        uart_tx_buf[3]  <=8'h4c;//l
        uart_tx_buf[4]  <=8'h4f;//o
        uart_tx_buf[5]  <=8'h20;//space
        uart_tx_buf[6]  <=8'h46;//f
        uart_tx_buf[7]  <=8'h50;//p
        uart_tx_buf[8]  <=8'h47;//g   
        uart_tx_buf[9]  <=8'h41;//a      
        uart_tx_buf[10]  <=8'h0d;//Enter
        uart_tx_buf[11]  <=8'h0a;//newline

        //各寄存器清零
        uart_wdata    <= 8'd0;
        uart_wreq     <= 1'b0;
        S_UART_TX       <= 2'd0;
        t1s_dly_en      <= 1'b0;
        tx_index        <= 4'd0;
    end
    else begin
        case(S_UART_TX)
        0:begin
            if(!uart_wbusy)begin//When the bus is not busy, request to send
                uart_wdata <= uart_tx_buf[tx_index];//准备发送数据,发送tx_index所指向的数据
                uart_wreq <= 1'b1;//设置uart_wreq为高电平,请求发送数据
            end
            else begin//当总线忙
                uart_wreq <= 1'b0; //重置uart_wreq
                S_UART_TX <= 2'd1;//进入下一状态
            end
        end
        1:begin//该状态等待总线空闲
            S_UART_TX <= (uart_wbusy == 1'b0) ? 2'd2: S_UART_TX;
        end 
        2:begin//更新tx_index计数器
            if(tx_index < 11)begin//每一帧发送11个字节
                tx_index <= tx_index + 1'b1; //tx_index+1计数
                S_UART_TX  <= 2'd0;//进入下一状态
            end
            else begin//如果tx_index==11 代表所有数据发送完毕
                tx_index   <= 4'd0;//重置tx_index
                t1s_dly_en <= 1'b1;//1s延迟计数器开始计数
                S_UART_TX  <= 2'd3;//下一状态
            end 
        end
        3:begin//1s延迟计数器计数
            //这里的1S不是精确的,仅以delay_cnt[24]最高位作为判断可以节省逻辑资源
            if(delay_cnt[24] == 1'b1)begin
                S_UART_TX <= 2'd0;  
                t1s_dly_en <= 1'b0;
            end
            else 
               S_UART_TX <= S_UART_TX;   
        end        
        endcase
    end   
    
end

//例化UART 发送驱动器模块   
uiuart_tx#
(
.BAUD_DIV(25000000/115200 -1) //波特率计算,BAUD_DIV = 系统时钟/波特率-1
)
uart_tx_u 
(
.I_clk(I_sysclk),
.I_uart_rstn(uart_rstn), 
.I_uart_wreq(uart_wreq), 
.I_uart_wdata(uart_wdata), 
.O_uart_wbusy(uart_wbusy),
.O_uart_tx(O_uart_tx)
);
    
endmodule
复制代码

module uart_top_tb;

reg I_sysclk;
wire O_uart_tx;

uart_top u_uart_top
(
.I_sysclk  (I_sysclk),
.O_uart_tx  (O_uart_tx)
);

initial begin
I_sysclk = 0;
#100;           
end

always  #20 I_sysclk = ~I_sysclk;
    
endmodule
复制代码