按键结构示意图

按键按下到松开的电平变化图

             按键消抖原理图

       按键消抖状态转换图

module key #
(
parameter REF_CLK = 32'd25000000    //设置时钟为参数,方便上层调用和修改
)
(
input  I_sysclk,
input  I_rstn,
input  I_key,
output O_key_down,
output O_key_up
);

//设置10MS的时钟分频计数
localparam  T10MS = (REF_CLK/100 - 1'b1);
//设置按键状态机的状态
localparam  KEY_S0 = 2'd0;
localparam  KEY_S1 = 2'd1;
localparam  KEY_S2 = 2'd2;
localparam  KEY_S3 = 2'd3;

reg [24:0] t10ms_cnt = 25'd0;
reg [3:0] key_r = 4'd0;
reg [1:0] key_s = 2'b0;
reg [1:0] key_s_r = 2'b0;
wire t10ms_done ;
 
assign t10ms_done = (t10ms_cnt == T10MS);//10ms计数是否完成
assign O_key_down   = (key_s == KEY_S2)&&( key_s_r == KEY_S1);//是否按下
assign O_key_up     = (key_s == KEY_S0)&&( key_s_r == KEY_S3);//是否弹起

//10ms timer counter
always @(posedge I_sysclk or negedge I_rstn)begin
    if(I_rstn == 1'b0)begin
        t10ms_cnt <= 25'd0;//复位
    end
    else if(t10ms_cnt < T10MS) 
        t10ms_cnt <= t10ms_cnt + 1'b1;//未计满则+1
    else 
        t10ms_cnt <= 25'd0;//计满则置0,开始新一轮计数
end

always @(posedge I_sysclk)begin
    key_s_r <= key_s;//将key_s的状态缓存一拍
end

always @(posedge I_sysclk)begin
    key_r <= {key_r[2:0],I_key};//将I_key的状态缓存一拍
end

always @(posedge I_sysclk or negedge I_rstn)begin
    if(I_rstn == 1'b0)begin
        key_s <= KEY_S0;
    end
    else if(t10ms_done)begin    //每10ms进行一次状态判断和转移
        case(key_s)
        KEY_S0:begin
           if(!key_r[3])    //收到第一个按键的低电平信号，不能判断是否为毛刺
               key_s <= KEY_S1;     //转到状态S1
        end  
        KEY_S1:begin//recheck key done  //第二次判断按键是否按下
           if(!key_r[3])
               key_s <= KEY_S2; //按下转入S2状态
            else 
               key_s <= KEY_S0; //没按下,判断为毛刺,转入S0状态,重新等待触发
        end 
        KEY_S2:begin//wait key up   //确定按键按下后
           if(key_r[3])   //等待按键松开,接收到按键的高电平信号
               key_s <= KEY_S3;  //不能确定是否为毛刺,转状态S3
        end  
        KEY_S3:begin//recheck key up
           if(key_r[3])  //第二次判断按键是否松开
              key_s <= KEY_S0; //依然检测到按键是松开的状态,转入S0状态,等待触发
        end
        endcase                  
    end
end

endmodule
复制代码

module key_top #
(
parameter REF_CLK = 32'd25000000
)
(
input  I_sysclk,
input  I_rstn,
input  I_key1,
input  I_key2,
output [3:0]O_LED
);

reg [3:0] LED_r;//存储LED灯的状态

wire key1_down,key2_down;
wire lock,clk0;

assign O_LED = LED_r;//将存储的LED灯的状态输出

pll pll_inst(
  .refclk(I_sysclk),
  .reset(~I_rstn),
  .extlock(lock),
  .clk0_out (clk0)
);


always @(posedge I_sysclk or negedge I_rstn)begin
    if(I_rstn == 1'b0) 
       LED_r <= 4'b0111; //设置LED的初始状态,低电平有效
    else if(key1_down)
       LED_r<={LED_r[2:0],LED_r[3]};//LED灯右移
    else if(key2_down)
       LED_r<={LED_r[0],LED_r[3:1]};//LED灯左移  
end
          

//例化两个按键,分别控制LED左右移动
key#(
.REF_CLK(REF_CLK)
)
key_u1
(
.I_sysclk(I_sysclk),
.I_rstn(I_rstn),
.I_key(I_key1),
.O_key_down(key1_down),
.O_key_up()
);

key#(
.REF_CLK(REF_CLK)
)
key_u2
(
.I_sysclk(I_sysclk),
.I_rstn(I_rstn),
.I_key(I_key2),
.O_key_down(key2_down),
.O_key_up()
);

endmodule
复制代码

module tb_key();

reg I_sysclk,I_rstn,I_key1,I_key2;
wire  [3:0]O_LED;

key_top#
(
.REF_CLK(25000000)
)
key_top_inst
(
.I_sysclk(I_sysclk), 
.I_rstn(I_rstn),
.I_key1(I_key1),
.I_key2(I_key2),
.O_LED(O_LED)
);

initial
        begin
                // Initialize Inputs
                I_sysclk = 0;
                I_rstn = 0;
                #100;
                I_rstn =1;
                I_key1 = 1;
                I_key2 = 1;
                #10000;
                forever
                        begin
                                I_key1 = 0;
                                // Wait 100 ns for global reset to finish
                                #100;
                                I_key1=1; #1000;
                                I_key1=0; #1000;
                                I_key1=1; #2000;
                                I_key1=0; #5000;
                                #20000000;
                                I_key1=1;
                                I_key1=0; #1000;
                I_key1=1; #2000;
                I_key1=0; #1000;
                I_key1=1; #2000;
                                #20000000;
                                I_key2=1; #1000;
                                I_key2=0; #1000;
                                I_key2=1; #2000;
                                I_key2=0; #5000;
                                #20000000;
                                I_key2=1;
                                I_key2=0; #1000;
                I_key2=1; #2000;
                I_key2=0; #1000;
                I_key2=1; #2000;
                                I_key2=0; #1000;        
                                #20000000;                
                                I_key2=1; #1000;        
                        end
        end

always #20 I_sysclk=~I_sysclk;


endmodule
复制代码

可以看到按键状态，key_down和key_up的情况，以及成功滤除了按键的抖动