[X]关闭
搜索

[米联客-XILINX-H3_CZ08_7100] FPGA基础篇连载-23 VTC视频时序控制器设计

文档创建者：FPGA课程
浏览次数：227
最后更新：2024-09-02
文档课程分类-AMD-ZYNQ
AMD-ZYNQ: ZYNQ-FPGA部分 » 2_FPGA实验篇(仅旗舰) » 1-FPGA基础入门实验
本帖最后由 FPGA课程 于 2024-9-2 10:41 编辑

​ 软件版本：VIVADO2021.1
操作系统：WIN10 64bit
硬件平台：适用 XILINX A7/K7/Z7/ZU/KU 系列 FPGA
实验平台：米联客-MLK-H3-CZ08-7100开发板
板卡获取平台：https://milianke.tmall.com/
登录“米联客”FPGA社区 http://www.uisrc.com 视频课程、答疑解惑！


1概述
Video Timing Controller 缩写VTC是我们在所有涉及FPGA图像、FPGA视频类方案中经常用到的一种用于产生视频时序的控制器。
2 VTC控制器设计2.1系统框图
VTC控制器通过hcnt和vcnt计数器实现hs时序vs时序以及de时序。
3a9845dd42314aa1abd861d8c7a2b967.jpg ​
2.2时序设计
视频数据在H_AcitiveSize和V_AcitiveSize同时有效时候有效，显示屏上的显示效果如下图所示。
67a5d5c7e16247ba80ee385ba48d1c83.jpg ​
3 VTC源码
  1. `timescale 1ns / 1ns //仿真时间刻度/精度

  3. module uivtc#
  4. (
  5. parameter H_ActiveSize  =   1980,               //视频时间参数,行视频信号，一行有效(需要显示的部分)像素所占的时钟数，一个时钟对应一个有效像素
  6. parameter H_FrameSize   =   1920+88+44+148,     //视频时间参数,行视频信号，一行视频信号总计占用的时钟数
  7. parameter H_SyncStart   =   1920+88,            //视频时间参数,行同步开始，即多少时钟数后开始产生行同步信号
  8. parameter H_SyncEnd     =   1920+88+44,         //视频时间参数,行同步结束，即多少时钟数后停止产生行同步信号，之后就是行有效数据部分

  10. parameter V_ActiveSize  =   1080,               //视频时间参数,场视频信号，一帧图像所占用的有效(需要显示的部分)行数量，通常说的视频分辨率即H_ActiveSize*V_ActiveSize
  11. parameter V_FrameSize   =   1080+4+5+36,        //视频时间参数,场视频信号，一帧视频信号总计占用的行数量
  12. parameter V_SyncStart   =   1080+4,             //视频时间参数,场同步开始，即多少行数后开始产生场同步信号
  13. parameter V_SyncEnd     =   1080+4+5            //视频时间参数,场同步结束，即多少场数后停止产生场同步信号，之后就是场有效数据部分
  14. )
  15. (
  16. input           I_vtc_rstn,     //系统复位
  17. input           I_vtc_sysclk_p,     
  18. input           I_vtc_sysclk_n,//系统时钟
  19. output          O_vtc_vs,       //场同步输出
  20. output          O_vtc_hs,       //行同步输出
  21. output          O_vtc_de_valid, //视频数据有效   
  22. output          O_vtc_user,     //满足stream时序产生 user 信号,用于帧同步
  23. output          O_vtc_last      //满足stream时序产生 later 信号,用于每行结束
  24. );

  26. wire I_clk;
  27. IBUFGDS CLK_U(
  28. .I(I_vtc_sysclk_p),
  29. .IB(I_vtc_sysclk_n),
  30. .O(I_clk)
  31. );

  33. reg [11:0] hcnt = 12'd0;    //视频水平方向，列计数器，寄存器
  34. reg [11:0] vcnt = 12'd0;    //视频垂直方向，行计数器，寄存器   
  35. reg [2 :0] rst_cnt = 3'd0;  //复位计数器，寄存器
  36. wire rst_sync = rst_cnt[2]; //同步复位

  38. always @(posedge I_clk or negedge I_vtc_rstn)begin //通过计数器产生同步复位
  39.     if(I_vtc_rstn == 1'b0)
  40.         rst_cnt <= 3'd0;
  41.     else if(rst_cnt[2] == 1'b0)
  42.         rst_cnt <= rst_cnt + 1'b1;
  43. end   

  45. //视频水平方向，列计数器
  46. always @(posedge I_clk)begin
  47.     if(rst_sync == 1'b0) //复位
  48.         hcnt <= 12'd0;
  49.     else if(hcnt < (H_FrameSize - 1'b1))//计数范围从0 ~ H_FrameSize-1
  50.         hcnt <= hcnt + 1'b1;
  51.     else
  52.         hcnt <= 12'd0;
  53. end         

  55. //视频垂直方向，行计数器，用于计数已经完成的行视频信号
  56. always @(posedge I_clk)begin
  57.     if(rst_sync == 1'b0)
  58.         vcnt <= 12'd0;
  59.     else if(hcnt == (H_ActiveSize  - 1'b1)) begin//视频水平方向，是否一行结束
  60.            vcnt <= (vcnt == (V_FrameSize - 1'b1)) ? 12'd0 : vcnt + 1'b1;//视频垂直方向，行计数器加1，计数范围0~V_FrameSize - 1
  61.     end
  62. end

  64. wire hs_valid  =  hcnt < H_ActiveSize; //行信号有效像素部分
  65. wire vs_valid  =  vcnt < V_ActiveSize; //场信号有效像素部分
  66. wire vtc_hs    =  (hcnt >= H_SyncStart && hcnt < H_SyncEnd);//产生hs，行同步信号
  67. wire vtc_vs    =  (vcnt > V_SyncStart && vcnt <= V_SyncEnd);//产生vs，场同步信号      
  68. wire vtc_de    =  hs_valid && vs_valid;//只有当视频水平方向，列有效和视频垂直方向，行同时有效，视频数据部分才是有效

  70. //**********************  video stream video rgb  ***************************
  71. //如果是输入RGB时序，那么转为stream时序
  72. reg   vtc_vs_r1  ;
  73. reg   vtc_hs_r1  ;
  74. reg   vtc_de_r1  ;
  75. reg   vtc_user_r1 ,vtc_user_r2;
  76. reg   vtc_valid_r1,vtc_valid_r2;
  77. reg   vtc_last_r2;
  78. reg   vs_start;

  80. always @(posedge I_clk )begin
  81.     if(rst_sync == 1'b0) //复位
  82.         vs_start <= 1'b0;
  83.     else if(vtc_user_r1)//清除VS帧同步
  84.         vs_start <= 1'b0;
  85.     else if(vtc_vs && vtc_vs_r1==1'b0)//当vtc_vs发生上升沿跳变代表一帧开始
  86.         vs_start <= 1'b1;
  87. end  
  88.       
  89. always @(posedge I_clk  )begin
  90.     vtc_vs_r1    <= vtc_vs;
  91.     vtc_hs_r1    <= vtc_hs;
  92.     vtc_user_r1  <= ~vtc_user_r1 & vs_start & vtc_de;//vtc_user延迟1拍
  93.     vtc_last_r2  <= ~vtc_de & vtc_valid_r1; //产生stream video last 延迟于数据输入2拍
  94.     vtc_valid_r1 <= vtc_de;//vtc_valid延迟1拍
  95.     vtc_valid_r2 <= vtc_valid_r1;//vtc_valid对输入信号延迟2拍，以和vtc_last_r2信号配套同步
  96.     vtc_user_r2  <= vtc_user_r1; //vtc_user 对输入信号延迟2拍，以和vtc_last_r2信号配套同步   
  97. end   

  99. assign O_vtc_vs       =  vtc_vs_r1;
  100. assign O_vtc_hs       =  vtc_hs_r1;
  101. assign O_vtc_de_valid =  vtc_valid_r2;
  102. assign O_vtc_user     =  vtc_user_r2;
  103. assign O_vtc_last     =  vtc_last_r2;

  105. endmodule
复制代码

4RTL仿真4.1仿真激励文件
为简化仿真，这里模拟的视频格式为320*5 即一行的有效数据为350个像素，一帧数据有5行像素数据。
  1. /*************视频时序测试仿真文件****************************************
  2. *********************************************************************/

  4. `timescale 1ns / 1ns //仿真时间刻度/精度

  6. module vtc_tb;

  8. localparam SYS_TIME = 10;//系统时钟周期10ns

  10. reg I_vid_rstn,I_vid_sysclk_p,I_vid_sysclk_n;
  11. wire O_vid_vs,O_vid_hs,O_vid_de,O_vtc_user,O_vtc_last;

  13. //例化视频时序产生模块
  14. uivtc#
  15. (
  16. .H_ActiveSize(320),         //视频时间参数,行视频信号，一行有效(需要显示的部分)像素所占的时钟数，一个时钟对应一个有效像素，设置320个像素
  17. .H_FrameSize(320+88+44+239),//视频时间参数,行视频信号，一行视频信号总计占用的时钟数
  18. .H_SyncStart(320+88),       //视频时间参数,行同步开始，即多少时钟数后开始产生行同步信号
  19. .H_SyncEnd(320+88+44),      //视频时间参数,行同步结束，即多少时钟数后停止产生行同步信号，之后就是行数据有效数据部分
  20. .V_ActiveSize(5),           //视频时间参数,场视频信号，一帧图像所占用的有效(需要显示的部分)行数量，通常说的视频分辨率即H_ActiveSize*V_ActiveSize
  21. .V_FrameSize(5+4+5+28),     //视频时间参数,场视频信号，一帧视频信号总计占用的行数量
  22. .V_SyncStart(5+4),          //视频时间参数,场同步开始，即多少行数后开始产生场同步信号
  23. .V_SyncEnd (5+4+5)        //视频时间参数,场同步结束，即多少行数后停止产生场同步信号，之后就是场有效数据部分
  24. )
  25. uivtc_inst
  26. (
  27. .I_vtc_sysclk_p(I_vid_sysclk_p),
  28. .I_vtc_sysclk_n(I_vid_sysclk_n),  //系统时钟
  29. .I_vtc_rstn(I_vid_rstn),//系统复位
  30. .O_vtc_vs(O_vid_vs),    //图形的vs信号
  31. .O_vtc_hs(O_vid_hs),    //图形的hs信号
  32. .O_vtc_de_valid(O_vid_de),    //de数据有效信号
  33. .O_vtc_user(O_vtc_user),
  34. .O_vtc_last(O_vtc_last)
  35. );

  37. initial begin
  38.     I_vid_sysclk_p  = 1'b0;
  39.     I_vid_sysclk_n  = 1'b1;
  40.     I_vid_rstn = 1'b0;
  41.     #100;
  42.     I_vid_rstn = 1'b1;
  43. end

  45. always #(SYS_TIME/2) I_vid_sysclk_p= ~I_vid_sysclk_p;
  46. always #(SYS_TIME/2) I_vid_sysclk_n= ~I_vid_sysclk_n;


  49. endmodule
复制代码

4.2仿真结果
804497a32b41462f82ea82c7cbddade5.jpg ​
5分辨率以及时钟计算方法
如果是标准分辨率，建议大家以标准分辨率参数直接填入，如果不是标准分辨率则根据实际情况可以用接近标准分辨率的参数去修改相关参数。
比如对于标准分辨率1080*1920*60的分辨率通常采用148.5MHZ的像素时钟。此时我们可以给出以下参数设置：
  1. H_ActiveSize    =1920
  2. H_SyncStart     =1920+88
  3. H_SyncEnd       =1920+88+44
  4. H_FrameSize     =1920+88+44+148
  5. V_ActiveSize    =1080
  6. V_SyncStart     =1080+4
  7. V_SyncEnd       =1080+4+5
  8. V_FrameSize     =1080+4+5+36
复制代码

计算分辨率和时钟的推断可以用一个关键公式 像素时钟= H_FrameSize* V_FrameSize*帧率，但是通常我们只会知道，H_ActiveSize、V_ActiveSize以及帧率，而像素时钟和其他参数都需要我们自己设置。
可以先以以上标准1080*1920*60的分辨率计算下：
H_FrameSize* V_FrameSize*帧率 = 2,200* 1,125*60= 148,500,000，在时钟晶振足够精确的情况下，可以确保帧率以恒定60fps输出。

但是很多时候如果某个参数不能满足要求，比如系统时钟只能提供140MHZ的情况，那么我们也可以重新调整参数，尽量来接近标准分辨率。
比如当以140MHZ输出1080*1920*60fps的视频时，我们给出以下参数：
  1. H_ActiveSize    =1920
  2. H_SyncStart     =1920+88
  3. H_SyncEnd       =1920+88+44
  4. H_FrameSize     =1920+88+44+71

  6. V_ActiveSize    =1080
  7. V_SyncStart     =1080+4
  8. V_SyncEnd       =1080+4+5
  9. V_FrameSize     =1080+4+5+16
复制代码

H_FrameSize* V_FrameSize *帧率=2,123*1099*60=139,990,620 这样每一帧的精确度误差为0.000067。对于140MHZ的时钟输出帧率会稍微快点。
6常用系统分辨率
对于148.5MHZ像素时钟，输出1080*1920*60
  1. H_ActiveSize    =1920
  2. H_SyncStart     =1920+88
  3. H_SyncEnd       =1920+88+44
  4. H_FrameSize     =1920+88+44+148
  5. V_ActiveSize    =1080
  6. V_SyncStart     =1080+4
  7. V_SyncEnd       =1080+4+5
  8. V_FrameSize     =1080+4+5+36
复制代码

对于74.25MHZ像素时钟，输出1280*720*60
  1. H_ActiveSize    =1280
  2. H_SyncStart     =1280+110
  3. H_SyncEnd       =1280+110+ 40
  4. H_FrameSize     =1280+110+ 40+220
  5. V_ActiveSize    =720
  6. V_SyncStart     =720+4
  7. V_SyncEnd       =720+4+5
  8. V_FrameSize     =720+4+5+21
复制代码

对于42MHZ像素时钟，输出640*480*60
  1. H_ActiveSize    =640
  2. H_SyncStart     =640+16
  3. H_SyncEnd       =640+16+96
  4. H_FrameSize     =640+16+96+48
  5. V_ActiveSize    =480
  6. V_SyncStart     =480+9
  7. V_SyncEnd       =480+9+2
  8. V_FrameSize     =480+9+2+34
复制代码

对于非标准分辨率，用户可以以上面介绍的方法计算相近参数。
比如对于非标准140MHZ像素时钟，输出1080*1920*60
  1. H_ActiveSize    =1920
  2. H_SyncStart     =1920+88
  3. H_SyncEnd       =1920+88+44
  4. H_FrameSize     =1920+88+44+71

  6. V_ActiveSize    =1080
  7. V_SyncStart     =1080+4
  8. V_SyncEnd       =1080+4+5
  9. V_FrameSize     =1080+4+5+16
复制代码


比如对于非标准75MHZ像素时钟，输出1280*720*60
  1. H_ActiveSize    =1280
  2. H_SyncStart     =1280+88
  3. H_SyncEnd       =1280+88+44
  4. H_FrameSize     =1280+88+44+239

  6. V_ActiveSize    =720
  7. V_SyncStart     =720+4
  8. V_SyncEnd       =720+4+5
  9. V_FrameSize     =720+4+5+28
复制代码


​

回复

使用道具 举报

高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

XILINX 官网| 站点统计| Archiver| 手机版| 米联客品牌主页|
版权所有 UISRC.COM Copyright © 2023-2026, 常州一二三电子科技有限公司. ( 苏ICP备19046771号-2 ) 站点内容版权归常州一二三电子科技有限公司所有，如侵犯您的权益，请联系客服处理